1С:Предприятие

Регламентные задания, которые сообщают о себе наружу.

Регламентные задания 1С отключаются тише всего: после обновления конфигурации или перезапуска сервера задание может остаться выключенным, и обнаруживается это на закрытии месяца.

Общий модуль «Мониторинг»

Процедура ОтправитьПинг(Суффикс = "", Тело = "") Экспорт

    Адрес = "https://ping.tickwatch.dev/ВАШ-КЛЮЧ" + ?(ПустаяСтрока(Суффикс), "", "/" + Суффикс);
    URI = ОбщегоНазначенияКлиентСервер.СтруктураURI(Адрес);

    Защищённое = НРег(URI.Схема) = "https";
    Соединение = Новый HTTPСоединение(
        URI.Хост, , , , ,
        10,
        ?(Защищённое, Новый ЗащищённоеСоединениеOpenSSL(), Неопределено));

    Запрос = Новый HTTPЗапрос(URI.ПутьНаСервере);
    Если НЕ ПустаяСтрока(Тело) Тогда
        Запрос.УстановитьТелоИзСтроки(Лев(Тело, 10000), КодировкаТекста.UTF8);
    КонецЕсли;

    Попытка
        Соединение.ВызватьHTTPМетод("POST", Запрос);
    Исключение
        // Мониторинг не должен ронять регламентное задание.
        ЗаписьЖурналаРегистрации("Tickwatch",
            УровеньЖурналаРегистрации.Предупреждение, , , ОписаниеОшибки());
    КонецПопытки;

КонецПроцедуры

В самом регламентном задании

Процедура ВыгрузкаВБанкКлиент() Экспорт

    Мониторинг.ОтправитьПинг("start");

    Попытка
        ВыполнитьВыгрузку();
        Мониторинг.ОтправитьПинг();
    Исключение
        Мониторинг.ОтправитьПинг("fail",
            ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));
        ВызватьИсключение;
    КонецПопытки;

КонецПроцедуры